59 lines
2.0 KiB
CMake
59 lines
2.0 KiB
CMake
# add the library that runs
|
|
add_library(MathFunctions MathFunctions.cxx)
|
|
|
|
# state that anybody linking to us needs to include the current source dir
|
|
# to find MathFunctions.h, while we don't.
|
|
target_include_directories(MathFunctions
|
|
INTERFACE
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
|
|
$<INSTALL_INTERFACE:include>
|
|
)
|
|
|
|
# should we use our own math functions
|
|
option(USE_MYMATH "Use tutorial provided math implementation" ON)
|
|
if(USE_MYMATH)
|
|
|
|
target_compile_definitions(MathFunctions PRIVATE "USE_MYMATH")
|
|
|
|
include(MakeTable.cmake) # generates Table.h
|
|
|
|
# library that just does sqrt
|
|
add_library(SqrtLibrary STATIC
|
|
mysqrt.cxx
|
|
${CMAKE_CURRENT_BINARY_DIR}/Table.h
|
|
)
|
|
|
|
# state that we depend on our binary dir to find Table.h
|
|
target_include_directories(SqrtLibrary PRIVATE
|
|
${CMAKE_CURRENT_BINARY_DIR}
|
|
)
|
|
|
|
# state that SqrtLibrary need PIC when the default is shared libraries
|
|
set_target_properties(SqrtLibrary PROPERTIES
|
|
POSITION_INDEPENDENT_CODE ${BUILD_SHARED_LIBS}
|
|
)
|
|
|
|
# link SqrtLibrary to tutorial_compiler_flags
|
|
target_link_libraries(SqrtLibrary PUBLIC tutorial_compiler_flags)
|
|
|
|
target_link_libraries(MathFunctions PRIVATE SqrtLibrary)
|
|
endif()
|
|
|
|
# link MathFunctions to tutorial_compiler_flags
|
|
target_link_libraries(MathFunctions PUBLIC tutorial_compiler_flags)
|
|
|
|
# define the symbol stating we are using the declspec(dllexport) when
|
|
# building on windows
|
|
target_compile_definitions(MathFunctions PRIVATE "EXPORTING_MYMATH")
|
|
|
|
# install libs
|
|
set(installable_libs MathFunctions tutorial_compiler_flags)
|
|
if(TARGET SqrtLibrary)
|
|
list(APPEND installable_libs SqrtLibrary)
|
|
endif()
|
|
install(TARGETS ${installable_libs}
|
|
EXPORT MathFunctionsTargets
|
|
DESTINATION lib)
|
|
# install include headers
|
|
install(FILES MathFunctions.h DESTINATION include)
|